remarks  file  generate/generate.inp
 remarks  Generate structure file and hydrogens for a protein

 topology  @TOPPAR:tophcsdx.pro  end                  {*Read topology file.*}
                     
 parameter 

@TOPPAR:parhcsdx.pro                             {*Read empirical potential*}
                                                 {*parameter file CHARMM19 *}
                                                 {*with modifications.     *}

   nbonds                                  {*This statement specifies the  *}
      atom cdie shift eps=1.0  e14fac=0.4  {*nonbonded interaction energy  *}
      cutnb=7.5 ctonnb=6.0 ctofnb=6.5      {*options.  Note the reduced    *}
      nbxmod=5 vswitch                     {*nonbonding cutoff to save some*}
   end                                     {*CPU time.   This statement    *}
                                           {*overwrites the defaults in    *}
                                           {*the parameter file.           *}
 end

 segment                                                {*Generate protein.*}

   name="    "                              {*This name has to match the   *}
                                            {*four characters in columns 73*}
                                            {*through 76 in the coordinate *}
                                            {*file; in XPLOR this name is  *}
                                            {*referred to as SEGId.        *}
   chain
     @TOPPAR:toph19.pep                      {*Read peptide bond file;     *}
     coordinates @Exercise1.pdb 
			                     {*interpret coordinate file to*}
   end                                       {*obtain the sequence.        *}
 end
                                                 {*Sometimes different atom*}
 {vector do (name="O") ( name OT1 )               {*names are used.         *}
 vector do (name="OT") ( name OT2 )}
 vector do (name="CD1") ( name CD and resname ile )
                                             
 coordinates @Exercise1.pdb
		 	                        {*Here we actually read the*}
                                                {*coordinates.             *}

                                          {*The generation of cofactors,   *}
                                          {*waters, etc. would follow here.*}
                                               {*Note that one has to split*}
                                               {*the coordinate file into  *}
  			                       {*separate files containing *}
                                               {*the protein, cofactors,   *}
                                               {*substrate, water, etc.    *}

                                                     {*Create a S-S bridge.*}
{  patch disu 
    reference=1=( resid 11 )  
    reference=2=( resid 27 )
  end
  patch disu 
    reference=1=( resid 45 )
    reference=2=( resid 73 )
  end
}

 flags exclude vdw elec end                {*Do QUICK hydrogen building w/o*}
                                           {*vdw and elec terms.           *}

 hbuild                                      {*This statement builds       *}
    selection=( hydrogen )                   {*missing hydrogens, which are*}
    phistep=45                               {*needed for the force field. *}
 end

 constraints fix=( not hydrogen ) end      {* Minimize hydrogen positions. *}
 flags include vdw elec end
 minimize powell 
    nstep=40 
 end
 constraints fix=( not all ) end 


 write coordinates output=generate.pdb end         {*Write out coordinates.*} 

 write structure output=generate.psf end        {*Write out structure file.*}
 stop